Started working on sample showing comparing separate/interleaved vertex attributes

data/shaders/glsl/vertexattributes/scene.frag

@@ -0,0 +1,43 @@
+#version 450
+
+layout (set = 1, binding = 0) uniform sampler2D samplerColorMap;
+layout (set = 1, binding = 1) uniform sampler2D samplerNormalMap;
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec2 inUV;
+layout (location = 2) in vec3 inViewVec;
+layout (location = 3) in vec3 inLightVec;
+layout (location = 4) in vec4 inTangent;
+
+layout (location = 0) out vec4 outFragColor;
+
+layout(push_constant) uniform PushConsts {
+	mat4 model;
+	uint alphaMask;
+	float alphaMaskCuttoff;
+} pushConsts;
+
+void main() 
+{
+	vec4 color = texture(samplerColorMap, inUV);
+
+	if (pushConsts.alphaMask == 1) {
+		if (color.a < pushConsts.alphaMaskCuttoff) {
+			discard;
+		}
+	}
+
+	vec3 N = normalize(inNormal);
+	vec3 T = normalize(inTangent.xyz);
+	vec3 B = cross(inNormal, inTangent.xyz) * inTangent.w;
+	mat3 TBN = mat3(T, B, N);
+	N = TBN * normalize(texture(samplerNormalMap, inUV).xyz * 2.0 - vec3(1.0));
+
+	const float ambient = 0.1;
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 diffuse = max(dot(N, L), ambient).rrr;
+	float specular = pow(max(dot(R, V), 0.0), 32.0);
+	outFragColor = vec4(diffuse * color.rgb + specular, color.a);
+}

data/shaders/glsl/vertexattributes/scene.vert

@@ -0,0 +1,39 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec4 inTangent;
+
+layout (set = 0, binding = 0) uniform UBOScene 
+{
+	mat4 projection;
+	mat4 view;
+	vec4 lightPos;
+	vec4 viewPos;
+} uboScene;
+
+layout(push_constant) uniform PushConsts {
+	mat4 model;
+	uint alphaMask;
+	float alphaMaskCuttoff;
+} pushConsts;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec2 outUV;
+layout (location = 2) out vec3 outViewVec;
+layout (location = 3) out vec3 outLightVec;
+layout (location = 4) out vec4 outTangent;
+
+void main() 
+{
+	outNormal = inNormal;
+	outUV = inUV;
+	outTangent = inTangent;
+	gl_Position = uboScene.projection * uboScene.view * pushConsts.model * vec4(inPos.xyz, 1.0);
+	
+	outNormal = mat3(pushConsts.model) * inNormal;
+	vec4 pos = pushConsts.model * vec4(inPos, 1.0);
+	outLightVec = uboScene.lightPos.xyz - pos.xyz;
+	outViewVec = uboScene.viewPos.xyz - pos.xyz;
+}