Moved shader into properly named sub folder

data/shaders/texturecubemap/reflect.frag

@@ -0,0 +1,35 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (binding = 1) uniform samplerCube samplerColor;
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in float inLodBias;
+layout (location = 3) in vec3 inViewVec;
+layout (location = 4) in vec3 inLightVec;
+layout (location = 5) in mat4 inInvModelView;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	vec3 cI = normalize (inPos);
+	vec3 cR = reflect (cI, normalize(inNormal));
+
+	cR = vec3(inInvModelView * vec4(cR, 0.0));
+	cR.x *= -1.0;
+
+	vec4 color = texture(samplerColor, cR, inLodBias);
+
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 ambient = vec3(0.5) * color.rgb;
+	vec3 diffuse = max(dot(N, L), 0.0) * vec3(1.0);
+	vec3 specular = pow(max(dot(R, V), 0.0), 16.0) * vec3(0.5);
+	outFragColor = vec4(ambient + diffuse * color.rgb + specular, 1.0);		
+}

data/shaders/texturecubemap/reflect.vert

@@ -0,0 +1,41 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 model;
+	float lodBias;
+} ubo;
+
+layout (location = 0) out vec3 outPos;
+layout (location = 1) out vec3 outNormal;
+layout (location = 2) out float outLodBias;
+layout (location = 3) out vec3 outViewVec;
+layout (location = 4) out vec3 outLightVec;
+layout (location = 5) out mat4 outInvModelView;
+
+out gl_PerVertex 
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	gl_Position = ubo.projection * ubo.model * vec4(inPos.xyz, 1.0);
+	
+	outPos = vec3(ubo.model * vec4(inPos, 1.0));
+	outNormal = mat3(ubo.model) * inNormal;	
+	outLodBias = ubo.lodBias;
+	
+	outInvModelView = inverse(ubo.model);
+
+	vec3 lightPos = vec3(0.0f, -5.0f, 5.0f);
+	outLightVec = lightPos.xyz - outPos.xyz;
+	outViewVec = -outPos.xyz;		
+}

data/shaders/texturecubemap/skybox.frag

@@ -0,0 +1,15 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (binding = 1) uniform samplerCube samplerCubeMap;
+
+layout (location = 0) in vec3 inUVW;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	outFragColor = texture(samplerCubeMap, inUVW);
+}

data/shaders/texturecubemap/skybox.vert

@@ -0,0 +1,26 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (location = 0) in vec3 inPos;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 model;
+} ubo;
+
+layout (location = 0) out vec3 outUVW;
+
+out gl_PerVertex 
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outUVW = inPos;
+	outUVW.x *= -1.0;
+	gl_Position = ubo.projection * ubo.model * vec4(inPos.xyz, 1.0);
+}