Moved shaders to new directory

shaders/glsl/geometryshader/base.frag

@@ -0,0 +1,10 @@
+#version 450
+
+layout (location = 0) in vec3 inColor;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main(void)
+{
+	outFragColor = vec4(inColor, 1.0);
+}

shaders/glsl/geometryshader/base.vert

@@ -0,0 +1,12 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+
+layout (location = 0) out vec3 outNormal;
+
+void main(void)
+{
+	outNormal = inNormal;
+	gl_Position = vec4(inPos.xyz, 1.0);
+}

shaders/glsl/geometryshader/mesh.frag

@@ -0,0 +1,20 @@
+#version 450
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inViewVec;
+layout (location = 3) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 ambient = vec3(0.1);
+	vec3 diffuse = max(dot(N, L), 0.0) * vec3(1.0);
+	vec3 specular = pow(max(dot(R, V), 0.0), 16.0) * vec3(0.75);
+	outFragColor = vec4((ambient + diffuse) * inColor.rgb + specular, 1.0);		
+}

shaders/glsl/geometryshader/mesh.vert

@@ -0,0 +1,30 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec3 inColor;
+
+layout (set = 0, binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 model;
+} ubo;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec3 outViewVec;
+layout (location = 3) out vec3 outLightVec;
+
+void main() 
+{
+	outNormal = inNormal;
+	outColor = inColor;
+	gl_Position = ubo.projection * ubo.model * vec4(inPos, 1.0);
+
+	vec4 pos = ubo.model * vec4(inPos, 1.0);
+	outNormal = mat3(ubo.model) * inNormal;
+
+	vec3 lightPos = vec3(1.0f, 1.0f, 1.0f);
+	outLightVec = lightPos.xyz - pos.xyz;
+	outViewVec = -pos.xyz;		
+}

shaders/glsl/geometryshader/normaldebug.geom

@@ -0,0 +1,34 @@
+#version 450
+
+layout (triangles) in;
+layout (line_strip, max_vertices = 6) out;
+
+layout (binding = 1) uniform UBO 
+{
+	mat4 projection;
+	mat4 model;
+} ubo;
+
+layout (location = 0) in vec3 inNormal[];
+
+layout (location = 0) out vec3 outColor;
+
+void main(void)
+{	
+	float normalLength = 0.02;
+	for(int i=0; i<gl_in.length(); i++)
+	{
+		vec3 pos = gl_in[i].gl_Position.xyz;
+		vec3 normal = inNormal[i].xyz;
+
+		gl_Position = ubo.projection * (ubo.model * vec4(pos, 1.0));
+		outColor = vec3(1.0, 0.0, 0.0);
+		EmitVertex();
+
+		gl_Position = ubo.projection * (ubo.model * vec4(pos + normal * normalLength, 1.0));
+		outColor = vec3(0.0, 0.0, 1.0);
+		EmitVertex();
+
+		EndPrimitive();
+	}
+}