Moved shaders to new directory

shaders/glsl/instancing/instancing.frag

@@ -0,0 +1,23 @@
+#version 450
+
+layout (binding = 1) uniform sampler2DArray samplerArray;
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inUV;
+layout (location = 3) in vec3 inViewVec;
+layout (location = 4) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	vec4 color = texture(samplerArray, inUV) * vec4(inColor, 1.0);	
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 diffuse = max(dot(N, L), 0.1) * inColor;
+	vec3 specular = (dot(N,L) > 0.0) ? pow(max(dot(R, V), 0.0), 16.0) * vec3(0.75) * color.r : vec3(0.0);
+	outFragColor = vec4(diffuse * color.rgb + specular, 1.0);		
+}

shaders/glsl/instancing/instancing.vert

@@ -0,0 +1,81 @@
+#version 450
+
+// Vertex attributes
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inColor;
+
+// Instanced attributes
+layout (location = 4) in vec3 instancePos;
+layout (location = 5) in vec3 instanceRot;
+layout (location = 6) in float instanceScale;
+layout (location = 7) in int instanceTexIndex;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 modelview;
+	vec4 lightPos;
+	float locSpeed;
+	float globSpeed;
+} ubo;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec3 outUV;
+layout (location = 3) out vec3 outViewVec;
+layout (location = 4) out vec3 outLightVec;
+
+void main() 
+{
+	outColor = inColor;
+	outUV = vec3(inUV, instanceTexIndex);
+
+	mat3 mx, my, mz;
+	
+	// rotate around x
+	float s = sin(instanceRot.x + ubo.locSpeed);
+	float c = cos(instanceRot.x + ubo.locSpeed);
+
+	mx[0] = vec3(c, s, 0.0);
+	mx[1] = vec3(-s, c, 0.0);
+	mx[2] = vec3(0.0, 0.0, 1.0);
+	
+	// rotate around y
+	s = sin(instanceRot.y + ubo.locSpeed);
+	c = cos(instanceRot.y + ubo.locSpeed);
+
+	my[0] = vec3(c, 0.0, s);
+	my[1] = vec3(0.0, 1.0, 0.0);
+	my[2] = vec3(-s, 0.0, c);
+	
+	// rot around z
+	s = sin(instanceRot.z + ubo.locSpeed);
+	c = cos(instanceRot.z + ubo.locSpeed);	
+	
+	mz[0] = vec3(1.0, 0.0, 0.0);
+	mz[1] = vec3(0.0, c, s);
+	mz[2] = vec3(0.0, -s, c);
+	
+	mat3 rotMat = mz * my * mx;
+
+	mat4 gRotMat;
+	s = sin(instanceRot.y + ubo.globSpeed);
+	c = cos(instanceRot.y + ubo.globSpeed);
+	gRotMat[0] = vec4(c, 0.0, s, 0.0);
+	gRotMat[1] = vec4(0.0, 1.0, 0.0, 0.0);
+	gRotMat[2] = vec4(-s, 0.0, c, 0.0);
+	gRotMat[3] = vec4(0.0, 0.0, 0.0, 1.0);	
+	
+	vec4 locPos = vec4(inPos.xyz * rotMat, 1.0);
+	vec4 pos = vec4((locPos.xyz * instanceScale) + instancePos, 1.0);
+
+	gl_Position = ubo.projection * ubo.modelview * gRotMat * pos;
+	outNormal = mat3(ubo.modelview * gRotMat) * inverse(rotMat) * inNormal;
+
+	pos = ubo.modelview * vec4(inPos.xyz + instancePos, 1.0);
+	vec3 lPos = mat3(ubo.modelview) * ubo.lightPos.xyz;
+	outLightVec = lPos - pos.xyz;
+	outViewVec = -pos.xyz;		
+}

shaders/glsl/instancing/planet.frag

@@ -0,0 +1,23 @@
+#version 450
+
+layout (binding = 1) uniform sampler2D samplerColorMap;
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inViewVec;
+layout (location = 4) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	vec4 color = texture(samplerColorMap, inUV) * vec4(inColor, 1.0) * 1.5;
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 diffuse = max(dot(N, L), 0.0) * inColor;
+	vec3 specular = pow(max(dot(R, V), 0.0), 4.0) * vec3(0.5) * color.r;
+	outFragColor = vec4(diffuse * color.rgb + specular, 1.0);		
+}

shaders/glsl/instancing/planet.vert

@@ -0,0 +1,32 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inColor;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 modelview;
+	vec4 lightPos;
+} ubo;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec2 outUV;
+layout (location = 3) out vec3 outViewVec;
+layout (location = 4) out vec3 outLightVec;
+
+void main() 
+{
+	outColor = inColor;
+	outUV = inUV;
+	gl_Position = ubo.projection * ubo.modelview * vec4(inPos.xyz, 1.0);
+	
+	vec4 pos = ubo.modelview * vec4(inPos, 1.0);
+	outNormal = mat3(ubo.modelview) * inNormal;
+	vec3 lPos = mat3(ubo.modelview) * ubo.lightPos.xyz;
+	outLightVec = lPos - pos.xyz;
+	outViewVec = -pos.xyz;		
+}

shaders/glsl/instancing/starfield.frag

@@ -0,0 +1,34 @@
+#version 450
+
+layout (location = 0) in vec3 inUVW;
+
+layout (location = 0) out vec4 outFragColor;
+
+#define HASHSCALE3 vec3(443.897, 441.423, 437.195)
+#define STARFREQUENCY 0.01
+
+// Hash function by Dave Hoskins (https://www.shadertoy.com/view/4djSRW)
+float hash33(vec3 p3)
+{
+	p3 = fract(p3 * HASHSCALE3);
+	p3 += dot(p3, p3.yxz+vec3(19.19));
+	return fract((p3.x + p3.y)*p3.z + (p3.x+p3.z)*p3.y + (p3.y+p3.z)*p3.x);
+}
+
+vec3 starField(vec3 pos)
+{
+	vec3 color = vec3(0.0);
+	float threshhold = (1.0 - STARFREQUENCY);
+	float rnd = hash33(pos);
+	if (rnd >= threshhold)
+	{
+		float starCol = pow((rnd - threshhold) / (1.0 - threshhold), 16.0);
+		color += vec3(starCol);
+	}	
+	return color;
+}
+
+void main() 
+{
+	outFragColor = vec4(starField(inUVW), 1.0);
+}

shaders/glsl/instancing/starfield.vert

@@ -0,0 +1,9 @@
+#version 450
+
+layout (location = 0) out vec3 outUVW;
+
+void main() 
+{
+	outUVW = vec3((gl_VertexIndex << 1) & 2, gl_VertexIndex & 2, gl_VertexIndex & 2);
+	gl_Position = vec4(outUVW.st * 2.0f - 1.0f, 0.0f, 1.0f);
+}