Moved shaders to new directory

shaders/glsl/offscreen/mirror.frag

@@ -0,0 +1,37 @@
+#version 450
+
+layout (binding = 1) uniform sampler2D samplerColor;
+
+layout (location = 0) in vec4 inPos;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	vec4 tmp = vec4(1.0 / inPos.w);
+	vec4 projCoord = inPos * tmp;
+
+	// Scale and bias
+	projCoord += vec4(1.0);
+	projCoord *= vec4(0.5);
+		
+	// Slow single pass blur
+	// For demonstration purposes only
+	const float blurSize = 1.0 / 512.0;	
+
+	outFragColor = vec4(vec3(0.0), 1.);
+
+	if (gl_FrontFacing) 
+	{
+		// Only render mirrored scene on front facing (upper) side of mirror surface
+		vec4 reflection = vec4(0.0);
+		for (int x = -3; x <= 3; x++)
+		{
+			for (int y = -3; y <= 3; y++)
+			{
+				reflection += texture(samplerColor, vec2(projCoord.s + x * blurSize, projCoord.t + y * blurSize)) / 49.0;
+			}
+		}
+		outFragColor += reflection;
+	};
+}

shaders/glsl/offscreen/mirror.vert

@@ -0,0 +1,18 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 view;
+	mat4 model;
+} ubo;
+
+layout (location = 0) out vec4 outPos;
+
+void main() 
+{
+	outPos = ubo.projection * ubo.view * ubo.model * vec4(inPos.xyz, 1.0);
+	gl_Position = outPos;		
+}

shaders/glsl/offscreen/phong.frag

@@ -0,0 +1,25 @@
+#version 450
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inEyePos;
+layout (location = 3) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	vec3 Eye = normalize(-inEyePos);
+	vec3 Reflected = normalize(reflect(-inLightVec, inNormal)); 
+
+	vec4 IAmbient = vec4(0.1, 0.1, 0.1, 1.0);
+	vec4 IDiffuse = vec4(max(dot(inNormal, inLightVec), 0.0));
+	float specular = 0.75;
+	vec4 ISpecular = vec4(0.0);
+	if (dot(inEyePos, inNormal) < 0.0)
+	{
+		ISpecular = vec4(0.5, 0.5, 0.5, 1.0) * pow(max(dot(Reflected, Eye), 0.0), 16.0) * specular; 
+	}
+
+	outFragColor = vec4((IAmbient + IDiffuse) * vec4(inColor, 1.0) + ISpecular);
+}

shaders/glsl/offscreen/phong.vert

@@ -0,0 +1,31 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inNormal;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 view;
+	mat4 model;
+	vec4 lightPos;
+} ubo;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec3 outEyePos;
+layout (location = 3) out vec3 outLightVec;
+
+void main() 
+{
+	outNormal = inNormal;
+	outColor = inColor;
+	gl_Position = ubo.projection * ubo.view * ubo.model * vec4(inPos, 1.0);
+	outEyePos = vec3(ubo.view * ubo.model * vec4(inPos, 1.0));
+	outLightVec = normalize(ubo.lightPos.xyz - outEyePos);
+
+	// Clip against reflection plane
+	vec4 clipPlane = vec4(0.0, -1.0, 0.0, 1.5);	
+	gl_ClipDistance[0] = dot(vec4(inPos, 1.0), clipPlane);	
+}

shaders/glsl/offscreen/quad.frag

@@ -0,0 +1,12 @@
+#version 450
+
+layout (binding = 1) uniform sampler2D samplerColor;
+
+layout (location = 0) in vec2 inUV;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+  outFragColor = texture(samplerColor, inUV);
+}

shaders/glsl/offscreen/quad.vert

@@ -0,0 +1,9 @@
+#version 450
+
+layout (location = 0) out vec2 outUV;
+
+void main() 
+{
+	outUV = vec2((gl_VertexIndex << 1) & 2, gl_VertexIndex & 2);
+	gl_Position = vec4(outUV * 2.0f - 1.0f, 0.0f, 1.0f);
+}