Moved shaders to new directory

shaders/hlsl/raytracingbasic/closesthit.rchit

@@ -0,0 +1,18 @@
+// Copyright 2020 Google LLC
+
+struct Attribute
+{
+  float2 attribs;
+};
+
+struct Payload
+{
+[[vk::location(0)]] float3 hitValue;
+};
+
+[shader("closesthit")]
+void main(inout Payload p, in float2 attribs)
+{
+  const float3 barycentricCoords = float3(1.0f - attribs.x - attribs.y, attribs.x, attribs.y);
+  p.hitValue = barycentricCoords;
+}

shaders/hlsl/raytracingbasic/miss.rmiss

@@ -0,0 +1,12 @@
+// Copyright 2020 Google LLC
+
+struct Payload
+{
+[[vk::location(0)]] float3 hitValue;
+};
+
+[shader("miss")]
+void main(inout Payload p)
+{
+    p.hitValue = float3(0.0, 0.0, 0.2);
+}

shaders/hlsl/raytracingbasic/raygen.rgen

@@ -0,0 +1,39 @@
+// Copyright 2020 Google LLC
+
+RaytracingAccelerationStructure rs : register(t0);
+RWTexture2D<float4> image : register(u1);
+
+struct CameraProperties
+{
+	float4x4 viewInverse;
+	float4x4 projInverse;
+};
+cbuffer cam : register(b2) { CameraProperties cam; };
+
+struct Payload
+{
+[[vk::location(0)]] float3 hitValue;
+};
+
+[shader("raygeneration")]
+void main()
+{
+	uint3 LaunchID = DispatchRaysIndex();
+	uint3 LaunchSize = DispatchRaysDimensions();
+
+	const float2 pixelCenter = float2(LaunchID.xy) + float2(0.5, 0.5);
+	const float2 inUV = pixelCenter/float2(LaunchSize.xy);
+	float2 d = inUV * 2.0 - 1.0;
+	float4 target = mul(cam.projInverse, float4(d.x, d.y, 1, 1));
+
+	RayDesc rayDesc;
+	rayDesc.Origin = mul(cam.viewInverse, float4(0,0,0,1)).xyz;
+	rayDesc.Direction = mul(cam.viewInverse, float4(normalize(target.xyz), 0)).xyz;
+	rayDesc.TMin = 0.001;
+	rayDesc.TMax = 10000.0;
+
+	Payload payload;
+	TraceRay(rs, RAY_FLAG_FORCE_OPAQUE, 0xff, 0, 0, 0, rayDesc, payload);
+
+	image[int2(LaunchID.xy)] = float4(payload.hitValue, 0.0);
+}