Moved shaders to new directory

shaders/hlsl/raytracingcallable/callable1.rcall

@@ -0,0 +1,15 @@
+// Copyright 2021 Sascha Willems
+
+struct CallData
+{
+    float3 outColor;
+};
+
+[shader("callable")]
+void main(inout CallData data)
+{
+    // Generate a checker board pattern
+	float2 pos = float2(DispatchRaysIndex().x / 8, DispatchRaysIndex().y / 8);
+	float col = (pos.x + (pos.y % 2.0)) % 2.0;
+	data.outColor = float3(col, col, col);
+}

shaders/hlsl/raytracingcallable/callable2.rcall

@@ -0,0 +1,12 @@
+// Copyright 2021 Sascha Willems
+
+struct CallData
+{
+    float3 outColor;
+};
+
+[shader("callable")]
+void main(inout CallData data)
+{
+	data.outColor = float3(0.0, 1.0, 0.0);
+}

shaders/hlsl/raytracingcallable/callable3.rcall

@@ -0,0 +1,15 @@
+// Copyright 2021 Sascha Willems
+
+struct CallData
+{
+    float3 outColor;
+};
+
+[shader("callable")]
+void main(inout CallData data)
+{
+    // Generate a checker board pattern
+	float2 pos = float2(DispatchRaysIndex().x / 8, DispatchRaysIndex().y / 8);
+	float col = pos.y % 2.0;
+	data.outColor = float3(col, col, col);
+}

shaders/hlsl/raytracingcallable/closesthit.rchit

@@ -0,0 +1,21 @@
+// Copyright 2021 Sascha Willems
+
+struct Payload
+{
+[[vk::location(0)]] float3 hitValue;
+};
+
+struct CallData
+{
+    float3 outColor;
+};
+
+[shader("closesthit")]
+void main(inout Payload p, in float2 attribs)
+{
+	// Execute the callable shader indexed by the current geometry being hit
+	// For our sample this means that the first callable shader in the SBT is invoked for the first triangle, the second callable shader for the second triangle, etc.
+	CallData callData;
+	CallShader(GeometryIndex(), callData);
+	p.hitValue = callData.outColor;
+}

shaders/hlsl/raytracingcallable/miss.rmiss

@@ -0,0 +1,12 @@
+// Copyright 2021 Sascha Willems
+
+struct Payload
+{
+[[vk::location(0)]] float3 hitValue;
+};
+
+[shader("miss")]
+void main(inout Payload p)
+{
+    p.hitValue = float3(0.0, 0.0, 0.2);
+}

shaders/hlsl/raytracingcallable/raygen.rgen

@@ -0,0 +1,39 @@
+// Copyright 2021 Sascha Willems
+
+RaytracingAccelerationStructure rs : register(t0);
+RWTexture2D<float4> image : register(u1);
+
+struct CameraProperties
+{
+	float4x4 viewInverse;
+	float4x4 projInverse;
+};
+cbuffer cam : register(b2) { CameraProperties cam; };
+
+struct Payload
+{
+[[vk::location(0)]] float3 hitValue;
+};
+
+[shader("raygeneration")]
+void main()
+{
+	uint3 LaunchID = DispatchRaysIndex();
+	uint3 LaunchSize = DispatchRaysDimensions();
+
+	const float2 pixelCenter = float2(LaunchID.xy) + float2(0.5, 0.5);
+	const float2 inUV = pixelCenter/float2(LaunchSize.xy);
+	float2 d = inUV * 2.0 - 1.0;
+	float4 target = mul(cam.projInverse, float4(d.x, d.y, 1, 1));
+
+	RayDesc rayDesc;
+	rayDesc.Origin = mul(cam.viewInverse, float4(0,0,0,1)).xyz;
+	rayDesc.Direction = mul(cam.viewInverse, float4(normalize(target.xyz), 0)).xyz;
+	rayDesc.TMin = 0.001;
+	rayDesc.TMax = 10000.0;
+
+	Payload payload;
+	TraceRay(rs, RAY_FLAG_FORCE_OPAQUE, 0xff, 0, 0, 0, rayDesc, payload);
+
+	image[int2(LaunchID.xy)] = float4(payload.hitValue, 0.0);
+}