Started work on variable rate shading sample

data/shaders/glsl/variablerateshading/scene.frag

@@ -0,0 +1,43 @@
+#version 450
+
+#extension GL_NV_shading_rate_image : require
+
+layout (set = 1, binding = 0) uniform sampler2D samplerColorMap;
+layout (set = 1, binding = 1) uniform sampler2D samplerNormalMap;
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inViewVec;
+layout (location = 4) in vec3 inLightVec;
+layout (location = 5) in vec4 inTangent;
+
+layout (location = 0) out vec4 outFragColor;
+
+layout (constant_id = 0) const bool ALPHA_MASK = false;
+layout (constant_id = 1) const float ALPHA_MASK_CUTOFF = 0.0f;
+
+void main() 
+{
+	vec4 color = texture(samplerColorMap, inUV) * vec4(inColor, 1.0);
+
+	if (ALPHA_MASK) {
+		if (color.a < ALPHA_MASK_CUTOFF) {
+			discard;
+		}
+	}
+
+	vec3 N = normalize(inNormal);
+	vec3 T = normalize(inTangent.xyz);
+	vec3 B = cross(inNormal, inTangent.xyz) * inTangent.w;
+	mat3 TBN = mat3(T, B, N);
+	N = TBN * normalize(texture(samplerNormalMap, inUV).xyz * 2.0 - vec3(1.0));
+
+	const float ambient = 0.1;
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 diffuse = max(dot(N, L), ambient).rrr;
+	float specular = pow(max(dot(R, V), 0.0), 32.0);
+	outFragColor = vec4(diffuse * color.rgb + specular, color.a);
+}

data/shaders/glsl/variablerateshading/scene.vert

@@ -0,0 +1,37 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inColor;
+layout (location = 4) in vec4 inTangent;
+
+layout (set = 0, binding = 0) uniform UBOScene 
+{
+	mat4 projection;
+	mat4 view;
+	mat4 model;
+	vec4 lightPos;
+	vec4 viewPos;
+} uboScene;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec2 outUV;
+layout (location = 3) out vec3 outViewVec;
+layout (location = 4) out vec3 outLightVec;
+layout (location = 5) out vec4 outTangent;
+
+void main() 
+{
+	outNormal = inNormal;
+	outColor = inColor;
+	outUV = inUV;
+	outTangent = inTangent;
+	gl_Position = uboScene.projection * uboScene.view * uboScene.model * vec4(inPos.xyz, 1.0);
+	
+	outNormal = mat3(uboScene.model) * inNormal;
+	vec4 pos = uboScene.model * vec4(inPos, 1.0);
+	outLightVec = uboScene.lightPos.xyz - pos.xyz;
+	outViewVec = uboScene.viewPos.xyz - pos.xyz;
+}