claude_code/procedural-3d-engine
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions

Add slang shader for instancing sample

Browse source
This commit is contained in:
Sascha Willems 2025-04-26 21:02:45 +02:00
parent 74e66c6b48
commit b6b4fccb2c
3 changed files with 218 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

106
shaders/slang/instancing/instancing.slang Normal file
View file

@ -0,0 +1,106 @@
/* Copyright (c) 2025, Sascha Willems
*
* SPDX-License-Identifier: MIT
*
*/
struct VSInput
{
float3 Pos : POSITION0;
float3 Normal : NORMAL0;
float2 UV : TEXCOORD0;
float3 Color : COLOR0;
// Instanced attributes
float3 instancePos : POSITION1;
float3 instanceRot : TEXCOORD1;
float instanceScale : TEXCOORD2;
int instanceTexIndex : TEXCOORD3;
};
struct VSOutput
{
float4 Pos : SV_POSITION;
float3 Normal;
float3 Color;
float3 UV;
float3 ViewVec;
float3 LightVec;
};
struct UBO
{
float4x4 projection;
float4x4 modelview;
float4 lightPos;
float locSpeed;
float globSpeed;
};
ConstantBuffer<UBO> ubo;
Sampler2DArray samplerArray;
[shader("vertex")]
VSOutput vertexMain(VSInput input)
{
VSOutput output;
output.Color = input.Color;
output.UV = float3(input.UV, input.instanceTexIndex);
// rotate around x
float s = sin(input.instanceRot.x + ubo.locSpeed);
float c = cos(input.instanceRot.x + ubo.locSpeed);
float3x3 mx = { c, -s, 0.0,
s, c, 0.0,
0.0, 0.0, 1.0 };
// rotate around y
s = sin(input.instanceRot.y + ubo.locSpeed);
c = cos(input.instanceRot.y + ubo.locSpeed);
float3x3 my = { c, 0.0, -s,
0.0, 1.0, 0.0,
s, 0.0, c };
// rot around z
s = sin(input.instanceRot.z + ubo.locSpeed);
c = cos(input.instanceRot.z + ubo.locSpeed);
float3x3 mz = { 1.0, 0.0, 0.0,
0.0, c, -s,
0.0, s, c };
float3x3 rotMat = mul(mz, mul(my, mx));
float4x4 gRotMat;
s = sin(input.instanceRot.y + ubo.globSpeed);
c = cos(input.instanceRot.y + ubo.globSpeed);
gRotMat[0] = float4(c, 0.0, -s, 0.0);
gRotMat[1] = float4(0.0, 1.0, 0.0, 0.0);
gRotMat[2] = float4(s, 0.0, c, 0.0);
gRotMat[3] = float4(0.0, 0.0, 0.0, 1.0);
float4 locPos = float4(mul(rotMat, input.Pos.xyz), 1.0);
float4 pos = float4((locPos.xyz * input.instanceScale) + input.instancePos, 1.0);
output.Pos = mul(ubo.projection, mul(ubo.modelview, mul(gRotMat, pos)));
output.Normal = mul((float3x3)mul(ubo.modelview, gRotMat), mul(rotMat, input.Normal));
pos = mul(ubo.modelview, float4(input.Pos.xyz + input.instancePos, 1.0));
float3 lPos = mul((float3x3)ubo.modelview, ubo.lightPos.xyz);
output.LightVec = lPos - pos.xyz;
output.ViewVec = -pos.xyz;
return output;
}
[shader("fragment")]
float4 fragmentMain(VSOutput input)
{
float4 color = samplerArray.Sample(input.UV) * float4(input.Color, 1.0);
float3 N = normalize(input.Normal);
float3 L = normalize(input.LightVec);
float3 V = normalize(input.ViewVec);
float3 R = reflect(-L, N);
float3 diffuse = max(dot(N, L), 0.1) * input.Color;
float3 specular = (dot(N,L) > 0.0) ? pow(max(dot(R, V), 0.0), 16.0) * float3(0.75, 0.75, 0.75) * color.r : float3(0.0, 0.0, 0.0);
return float4(diffuse * color.rgb + specular, 1.0);
}

62
shaders/slang/instancing/planet.slang Normal file
View file

@ -0,0 +1,62 @@
/* Copyright (c) 2025, Sascha Willems
*
* SPDX-License-Identifier: MIT
*
*/
struct VSInput
{
float3 Pos;
float3 Normal;
float2 UV;
float3 Color;
};
struct VSOutput
{
float4 Pos : SV_POSITION;
float3 Normal;
float3 Color;
float2 UV;
float3 ViewVec;
float3 LightVec;
};
struct UBO
{
float4x4 projection;
float4x4 modelview;
float4 lightPos;
};
ConstantBuffer<UBO> ubo;
Sampler2D samplerColorMap;
[shader("vertex")]
VSOutput vertexMain(VSInput input)
{
VSOutput output;
output.Color = input.Color;
output.UV = input.UV;
output.Pos = mul(ubo.projection, mul(ubo.modelview, float4(input.Pos.xyz, 1.0)));
float4 pos = mul(ubo.modelview, float4(input.Pos, 1.0));
output.Normal = mul((float3x3)ubo.modelview, input.Normal);
float3 lPos = mul((float3x3)ubo.modelview, ubo.lightPos.xyz);
output.LightVec = lPos - pos.xyz;
output.ViewVec = -pos.xyz;
return output;
}
[shader("fragment")]
float4 fragmentMain(VSOutput input)
{
float4 color = samplerColorMap.Sample(input.UV) * float4(input.Color, 1.0) * 1.5;
float3 N = normalize(input.Normal);
float3 L = normalize(input.LightVec);
float3 V = normalize(input.ViewVec);
float3 R = reflect(-L, N);
float3 diffuse = max(dot(N, L), 0.0) * input.Color;
float3 specular = pow(max(dot(R, V), 0.0), 4.0) * float3(0.5, 0.5, 0.5) * color.r;
return float4(diffuse * color.rgb + specular, 1.0);
}

50
shaders/slang/instancing/starfield.slang Normal file
View file

@ -0,0 +1,50 @@
/* Copyright (c) 2025, Sascha Willems
*
* SPDX-License-Identifier: MIT
*
*/
#define HASHSCALE3 float3(443.897, 441.423, 437.195)
#define STARFREQUENCY 0.01
// Hash function by Dave Hoskins (https://www.shadertoy.com/view/4djSRW)
float hash33(float3 p3)
{
p3 = frac(p3 * HASHSCALE3);
p3 += dot(p3, p3.yxz+float3(19.19, 19.19, 19.19));
return frac((p3.x + p3.y)*p3.z + (p3.x+p3.z)*p3.y + (p3.y+p3.z)*p3.x);
}
float3 starField(float3 pos)
{
float3 color = float3(0.0, 0.0, 0.0);
float threshhold = (1.0 - STARFREQUENCY);
float rnd = hash33(pos);
if (rnd >= threshhold)
{
float starCol = pow((rnd - threshhold) / (1.0 - threshhold), 16.0);
color += starCol.xxx;
}
return color;
}
struct VSOutput
{
float4 Pos : SV_POSITION;
float3 UVW;
};
[shader("vertex")]
VSOutput vertexMain(uint VertexIndex: SV_VertexID)
{
VSOutput output;
output.UVW = float3((VertexIndex << 1) & 2, VertexIndex & 2, VertexIndex & 2);
output.Pos = float4(output.UVW.xy * 2.0f - 1.0f, 0.0f, 1.0f);
return output;
}
[shader("fragment")]
float4 fragmentMain(VSOutput input)
{
return float4(starField(input.UVW), 1.0);
}