Move shaders into glsl and hlsl directories

Move `data/shaders` to `data/shaders/glsl`
Move `data/hlsl` to `data/shaders/hlsl`

Fix up shader paths in the cpp files to point to the new glsl location.

`data/shaders/hlsl/compile.py` still overwrites the glsl .spv files (for
now).

Issue: #723

data/shaders/glsl/indirectdraw/generate-spirv.bat

@@ -0,0 +1,6 @@
+glslangvalidator -V ground.vert -o ground.vert.spv
+glslangvalidator -V ground.frag -o ground.frag.spv
+glslangvalidator -V indirectdraw.vert -o indirectdraw.vert.spv
+glslangvalidator -V indirectdraw.frag -o indirectdraw.frag.spv
+glslangvalidator -V skysphere.vert -o skysphere.vert.spv
+glslangvalidator -V skysphere.frag -o skysphere.frag.spv

data/shaders/glsl/indirectdraw/ground.frag

@@ -0,0 +1,25 @@
+#version 450
+
+layout (binding = 2) uniform sampler2D samplerColor;
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inViewVec;
+layout (location = 4) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	// Last array layer is terrain tex
+	vec4 color = texture(samplerColor, inUV);
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 ambient = vec3(0.65);
+	vec3 diffuse = max(dot(N, L), 0.0) * inColor;
+	vec3 specular = pow(max(dot(R, V), 0.0), 16.0) * vec3(0.1);
+	outFragColor = vec4((ambient + diffuse) * color.rgb + specular, 1.0);		
+}

data/shaders/glsl/indirectdraw/ground.vert

@@ -0,0 +1,40 @@
+#version 450
+
+// Vertex attributes
+layout (location = 0) in vec4 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inColor;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 modelview;
+} ubo;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec2 outUV;
+layout (location = 3) out vec3 outViewVec;
+layout (location = 4) out vec3 outLightVec;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outColor = inColor;
+	outUV = inUV * 32.0;
+	outNormal = inNormal;
+
+	vec4 pos = vec4(inPos.xyz, 1.0);
+
+	gl_Position = ubo.projection * ubo.modelview * pos;
+	
+	vec4 wPos = ubo.modelview * vec4(pos.xyz, 1.0); 
+	vec4 lPos = vec4(0.0, -5.0, 0.0, 1.0);
+	outLightVec = lPos.xyz - pos.xyz;
+	outViewVec = -pos.xyz;	
+}

data/shaders/glsl/indirectdraw/indirectdraw.frag

@@ -0,0 +1,27 @@
+#version 450
+
+layout (binding = 1) uniform sampler2DArray samplerArray;
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inUV;
+layout (location = 3) in vec3 inViewVec;
+layout (location = 4) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main()
+{
+	vec4 color = texture(samplerArray, inUV);
+
+	if (color.a < 0.5)
+	{
+		discard;
+	}
+
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 ambient = vec3(0.65);
+	vec3 diffuse = max(dot(N, L), 0.0) * inColor;
+	outFragColor = vec4((ambient + diffuse) * color.rgb, 1.0);
+}

data/shaders/glsl/indirectdraw/indirectdraw.vert

@@ -0,0 +1,79 @@
+#version 450
+
+// Vertex attributes
+layout (location = 0) in vec4 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec2 inUV;
+layout (location = 3) in vec3 inColor;
+
+// Instanced attributes
+layout (location = 4) in vec3 instancePos;
+layout (location = 5) in vec3 instanceRot;
+layout (location = 6) in float instanceScale;
+layout (location = 7) in int instanceTexIndex;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 modelview;
+} ubo;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec3 outUV;
+layout (location = 3) out vec3 outViewVec;
+layout (location = 4) out vec3 outLightVec;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outColor = inColor;
+	outUV = vec3(inUV, instanceTexIndex);
+	outUV.t = 1.0 - outUV.t;
+
+	mat4 mx, my, mz;
+	
+	// rotate around x
+	float s = sin(instanceRot.x);
+	float c = cos(instanceRot.x);
+
+	mx[0] = vec4(c, s, 0.0, 0.0);
+	mx[1] = vec4(-s, c, 0.0, 0.0);
+	mx[2] = vec4(0.0, 0.0, 1.0, 0.0);
+	mx[3] = vec4(0.0, 0.0, 0.0, 1.0);	
+	
+	// rotate around y
+	s = sin(instanceRot.y);
+	c = cos(instanceRot.y);
+
+	my[0] = vec4(c, 0.0, s, 0.0);
+	my[1] = vec4(0.0, 1.0, 0.0, 0.0);
+	my[2] = vec4(-s, 0.0, c, 0.0);
+	my[3] = vec4(0.0, 0.0, 0.0, 1.0);	
+	
+	// rot around z
+	s = sin(instanceRot.z);
+	c = cos(instanceRot.z);	
+	
+	mz[0] = vec4(1.0, 0.0, 0.0, 0.0);
+	mz[1] = vec4(0.0, c, s, 0.0);
+	mz[2] = vec4(0.0, -s, c, 0.0);
+	mz[3] = vec4(0.0, 0.0, 0.0, 1.0);	
+	
+	mat4 rotMat = mz * my * mx;
+		
+	outNormal = inNormal * mat3(rotMat);
+	
+	vec4 pos = vec4((inPos.xyz * instanceScale) + instancePos, 1.0) * rotMat;
+
+	gl_Position = ubo.projection * ubo.modelview * pos;
+	
+	vec4 wPos = ubo.modelview * vec4(pos.xyz, 1.0); 
+	vec4 lPos = vec4(0.0, -5.0, 0.0, 1.0);
+	outLightVec = lPos.xyz - pos.xyz;
+	outViewVec = -pos.xyz;	
+}

data/shaders/glsl/indirectdraw/skysphere.frag

@@ -0,0 +1,14 @@
+#version 450
+
+layout (binding = 2) uniform sampler2D samplerColor;
+
+layout (location = 0) in vec2 inUV;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	const vec4 gradientStart = vec4(0.93, 0.9, 0.81, 1.0);
+	const vec4 gradientEnd = vec4(0.35, 0.5, 1.0, 1.0);
+	outFragColor = mix(gradientStart, gradientEnd, min(0.5 - inUV.t, 0.5)/0.15 + 0.5);
+}

data/shaders/glsl/indirectdraw/skysphere.vert

@@ -0,0 +1,25 @@
+#version 450
+
+// Vertex attributes
+layout (location = 0) in vec4 inPos;
+layout (location = 2) in vec2 inUV;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 modelview;
+} ubo;
+
+layout (location = 0) out vec2 outUV;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outUV = vec2(inUV.s, 1.0-inUV.t);
+	// Skysphere always at center, only use rotation part of modelview matrix
+	gl_Position = ubo.projection * mat4(mat3(ubo.modelview)) * vec4(inPos.xyz, 1.0);
+}