Move shaders into glsl and hlsl directories

Move `data/shaders` to `data/shaders/glsl`
Move `data/hlsl` to `data/shaders/hlsl`

Fix up shader paths in the cpp files to point to the new glsl location.

`data/shaders/hlsl/compile.py` still overwrites the glsl .spv files (for
now).

Issue: #723

data/shaders/glsl/multiview/multiview.frag

@@ -0,0 +1,20 @@
+#version 450
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inViewVec;
+layout (location = 3) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outColor;
+
+void main() 
+{
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 ambient = vec3(0.1);
+	vec3 diffuse = max(dot(N, L), 0.0) * vec3(1.0);
+	vec3 specular = pow(max(dot(R, V), 0.0), 16.0) * vec3(0.75);
+	outColor = vec4((ambient + diffuse) * inColor.rgb + specular, 1.0);		
+}

data/shaders/glsl/multiview/multiview.vert

@@ -0,0 +1,40 @@
+#version 450
+
+#extension GL_EXT_multiview : enable
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec3 inColor;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec3 outViewVec;
+layout (location = 3) out vec3 outLightVec;
+
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection[2];
+	mat4 modelview[2];
+	vec4 lightPos;
+} ubo;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outColor = inColor;
+	outNormal = mat3(ubo.modelview[gl_ViewIndex]) * inNormal;
+
+	vec4 pos = vec4(inPos.xyz, 1.0);
+	vec4 worldPos = ubo.modelview[gl_ViewIndex] * pos;
+		
+	vec3 lPos = vec3(ubo.modelview[gl_ViewIndex] * ubo.lightPos);
+	outLightVec = lPos - worldPos.xyz;
+	outViewVec = -worldPos.xyz;	
+
+	gl_Position = ubo.projection[gl_ViewIndex] * worldPos;
+}

data/shaders/glsl/multiview/viewdisplay.frag

@@ -0,0 +1,25 @@
+#version 450
+
+layout (binding = 1) uniform sampler2DArray samplerView;
+
+layout (binding = 0) uniform UBO 
+{
+	layout(offset = 272) float distortionAlpha;
+} ubo;
+
+layout (location = 0) in vec2 inUV;
+layout (location = 0) out vec4 outColor;
+
+layout (constant_id = 0) const float VIEW_LAYER = 0.0f;
+
+void main() 
+{
+	const float alpha = ubo.distortionAlpha;
+
+	vec2 p1 = vec2(2.0 * inUV - 1.0);
+	vec2 p2 = p1 / (1.0 - alpha * length(p1));
+	p2 = (p2 + 1.0) * 0.5;
+
+	bool inside = ((p2.x >= 0.0) && (p2.x <= 1.0) && (p2.y >= 0.0 ) && (p2.y <= 1.0));
+	outColor = inside ? texture(samplerView, vec3(p2, VIEW_LAYER)) : vec4(0.0);
+}

data/shaders/glsl/multiview/viewdisplay.vert

@@ -0,0 +1,14 @@
+#version 450
+
+layout (location = 0) out vec2 outUV;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outUV = vec2((gl_VertexIndex << 1) & 2, gl_VertexIndex & 2);
+	gl_Position = vec4(outUV * 2.0f - 1.0f, 0.0f, 1.0f);
+}