Move shaders into glsl and hlsl directories

Move `data/shaders` to `data/shaders/glsl`
Move `data/hlsl` to `data/shaders/hlsl`

Fix up shader paths in the cpp files to point to the new glsl location.

`data/shaders/hlsl/compile.py` still overwrites the glsl .spv files (for
now).

Issue: #723

data/shaders/glsl/shadowmapping/generate-spirv.bat

@@ -0,0 +1,7 @@
+glslangvalidator -V offscreen.vert -o offscreen.vert.spv
+glslangvalidator -V offscreen.frag -o offscreen.frag.spv
+glslangvalidator -V quad.vert -o quad.vert.spv
+glslangvalidator -V quad.frag -o quad.frag.spv
+glslangvalidator -V scene.vert -o scene.vert.spv
+glslangvalidator -V scene.frag -o scene.frag.spv
+

data/shaders/glsl/shadowmapping/offscreen.frag

@@ -0,0 +1,8 @@
+#version 450
+
+layout(location = 0) out vec4 color;
+
+void main() 
+{	
+	color = vec4(1.0, 0.0, 0.0, 1.0);
+}

data/shaders/glsl/shadowmapping/offscreen.vert

@@ -0,0 +1,19 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 depthMVP;
+} ubo;
+
+out gl_PerVertex 
+{
+    vec4 gl_Position;   
+};
+
+ 
+void main()
+{
+	gl_Position =  ubo.depthMVP * vec4(inPos, 1.0);
+}

data/shaders/glsl/shadowmapping/quad.frag

@@ -0,0 +1,21 @@
+#version 450
+
+layout (binding = 1) uniform sampler2D samplerColor;
+
+layout (location = 0) in vec2 inUV;
+
+layout (location = 0) out vec4 outFragColor;
+
+float LinearizeDepth(float depth)
+{
+  float n = 1.0; // camera z near
+  float f = 128.0; // camera z far
+  float z = depth;
+  return (2.0 * n) / (f + n - z * (f - n));	
+}
+
+void main() 
+{
+	float depth = texture(samplerColor, inUV).r;
+	outFragColor = vec4(vec3(1.0-LinearizeDepth(depth)), 1.0);
+}

data/shaders/glsl/shadowmapping/quad.vert

@@ -0,0 +1,14 @@
+#version 450
+
+layout (location = 0) out vec2 outUV;
+
+out gl_PerVertex 
+{
+	vec4 gl_Position;   
+};
+
+void main() 
+{
+	outUV = vec2((gl_VertexIndex << 1) & 2, gl_VertexIndex & 2);
+	gl_Position = vec4(outUV, 0.0f, 1.0f);
+}

data/shaders/glsl/shadowmapping/scene.frag

@@ -0,0 +1,66 @@
+#version 450
+
+layout (binding = 1) uniform sampler2D shadowMap;
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inViewVec;
+layout (location = 3) in vec3 inLightVec;
+layout (location = 4) in vec4 inShadowCoord;
+
+layout (constant_id = 0) const int enablePCF = 0;
+
+layout (location = 0) out vec4 outFragColor;
+
+#define ambient 0.1
+
+float textureProj(vec4 shadowCoord, vec2 off)
+{
+	float shadow = 1.0;
+	if ( shadowCoord.z > -1.0 && shadowCoord.z < 1.0 ) 
+	{
+		float dist = texture( shadowMap, shadowCoord.st + off ).r;
+		if ( shadowCoord.w > 0.0 && dist < shadowCoord.z ) 
+		{
+			shadow = ambient;
+		}
+	}
+	return shadow;
+}
+
+float filterPCF(vec4 sc)
+{
+	ivec2 texDim = textureSize(shadowMap, 0);
+	float scale = 1.5;
+	float dx = scale * 1.0 / float(texDim.x);
+	float dy = scale * 1.0 / float(texDim.y);
+
+	float shadowFactor = 0.0;
+	int count = 0;
+	int range = 1;
+	
+	for (int x = -range; x <= range; x++)
+	{
+		for (int y = -range; y <= range; y++)
+		{
+			shadowFactor += textureProj(sc, vec2(dx*x, dy*y));
+			count++;
+		}
+	
+	}
+	return shadowFactor / count;
+}
+
+void main() 
+{	
+	float shadow = (enablePCF == 1) ? filterPCF(inShadowCoord / inShadowCoord.w) : textureProj(inShadowCoord / inShadowCoord.w, vec2(0.0));
+
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = normalize(-reflect(L, N));
+	vec3 diffuse = max(dot(N, L), ambient) * inColor;
+
+	outFragColor = vec4(diffuse * shadow, 1.0);
+
+}

data/shaders/glsl/shadowmapping/scene.vert

@@ -0,0 +1,48 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec2 inUV;
+layout (location = 2) in vec3 inColor;
+layout (location = 3) in vec3 inNormal;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 view;
+	mat4 model;
+	mat4 lightSpace;
+	vec3 lightPos;
+} ubo;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec3 outViewVec;
+layout (location = 3) out vec3 outLightVec;
+layout (location = 4) out vec4 outShadowCoord;
+
+out gl_PerVertex 
+{
+    vec4 gl_Position;   
+};
+
+const mat4 biasMat = mat4( 
+	0.5, 0.0, 0.0, 0.0,
+	0.0, 0.5, 0.0, 0.0,
+	0.0, 0.0, 1.0, 0.0,
+	0.5, 0.5, 0.0, 1.0 );
+
+void main() 
+{
+	outColor = inColor;
+	outNormal = inNormal;
+
+	gl_Position = ubo.projection * ubo.view * ubo.model * vec4(inPos.xyz, 1.0);
+	
+    vec4 pos = ubo.model * vec4(inPos, 1.0);
+    outNormal = mat3(ubo.model) * inNormal;
+    outLightVec = normalize(ubo.lightPos - inPos);
+    outViewVec = -pos.xyz;			
+
+	outShadowCoord = ( biasMat * ubo.lightSpace * ubo.model ) * vec4(inPos, 1.0);	
+}
+