Added basic HDR rendering example (wip)

data/shaders/hdr/bloom.frag

@@ -0,0 +1,66 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (binding = 0) uniform sampler2D samplerColor0;
+layout (binding = 1) uniform sampler2D samplerColor1;
+
+layout (location = 0) in vec2 inUV;
+
+layout (location = 0) out vec4 outColor;
+
+layout (constant_id = 0) const int dir = 0;
+
+void main(void)
+{
+	// From the OpenGL Super bible
+	const float weights[] = float[](0.0024499299678342,
+									0.0043538453346397,
+									0.0073599963704157,
+									0.0118349786570722,
+									0.0181026699707781,
+									0.0263392293891488,
+									0.0364543006660986,
+									0.0479932050577658,
+									0.0601029809166942,
+									0.0715974486241365,
+									0.0811305381519717,
+									0.0874493212267511,
+									0.0896631113333857,
+									0.0874493212267511,
+									0.0811305381519717,
+									0.0715974486241365,
+									0.0601029809166942,
+									0.0479932050577658,
+									0.0364543006660986,
+									0.0263392293891488,
+									0.0181026699707781,
+									0.0118349786570722,
+									0.0073599963704157,
+									0.0043538453346397,
+									0.0024499299678342);
+
+
+	const float blurScale = 0.003;
+	const float blurStrength = 1.0;
+
+	float ar = 1.0;
+	// Aspect ratio for vertical blur pass
+	if (dir == 1)
+	{
+		vec2 ts = textureSize(samplerColor1, 0);
+		ar = ts.y / ts.x;
+	}
+
+	vec2 P = inUV.yx - vec2(0, (weights.length() >> 1) * ar * blurScale);
+
+	vec4 color = vec4(0.0);
+	for (int i = 0; i < weights.length(); i++)
+	{
+		vec2 dv = vec2(0.0, i * blurScale) * ar;
+		color += texture(samplerColor1, P + dv) * weights[i] * blurStrength;
+	}
+
+	outColor = color;
+}

data/shaders/hdr/bloom.vert

@@ -0,0 +1,17 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (location = 0) out vec2 outUV;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outUV = vec2((gl_VertexIndex << 1) & 2, gl_VertexIndex & 2);
+	gl_Position = vec4(outUV * 2.0f - 1.0f, 0.0f, 1.0f);
+}

data/shaders/hdr/composition.frag

@@ -0,0 +1,16 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (binding = 0) uniform sampler2D samplerColor0;
+layout (binding = 1) uniform sampler2D samplerColor1;
+
+layout (location = 0) in vec2 inUV;
+
+layout (location = 0) out vec4 outColor;
+
+void main() 
+{
+	outColor = texture(samplerColor0, inUV);
+}

data/shaders/hdr/composition.vert

@@ -0,0 +1,17 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (location = 0) out vec2 outUV;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outUV = vec2((gl_VertexIndex << 1) & 2, gl_VertexIndex & 2);
+	gl_Position = vec4(outUV * 2.0f - 1.0f, 0.0f, 1.0f);
+}

data/shaders/hdr/gbuffer.frag

@@ -0,0 +1,101 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (binding = 1) uniform sampler2D samplerEnvMap;
+
+layout (location = 0) in vec3 inUVW;
+layout (location = 1) in vec3 inPos;
+layout (location = 2) in vec3 inNormal;
+layout (location = 3) in vec3 inViewVec;
+layout (location = 4) in vec3 inLightVec;
+layout (location = 5) in mat4 inInvModelView;
+
+layout (location = 0) out vec4 outColor0;
+layout (location = 1) out vec4 outColor1;
+
+layout (constant_id = 0) const int type = 0;
+
+#define PI 3.1415926
+#define TwoPI (2.0 * PI)
+
+layout (binding = 2) uniform UBO {
+	float exposure;
+} ubo;
+
+vec2 envMapEquirect(vec3 normal) 
+{
+	float phi = acos(-normal.y);
+	float theta = atan(-1.0 * normal.x, normal.z) + PI;
+	return vec2(theta / TwoPI, phi / PI);
+}
+
+void main() 
+{
+	vec4 color;
+	vec3 wcNormal;
+
+	switch (type) {
+		case 0: // Skybox			
+			{
+				vec3 normal = normalize(inUVW);
+				color = texture(samplerEnvMap, envMapEquirect(normal));
+			}
+			break;
+		
+		case 1: // Reflect
+			{
+				vec3 wViewVec = mat3(inInvModelView) * normalize(inViewVec);
+				vec3 normal = normalize(inNormal);
+				vec3 wNormal = mat3(inInvModelView) * normal;
+
+				float NdotL = max(dot(normal, inLightVec), 0.0);
+
+				vec3 eyeDir = normalize(inViewVec);		
+				vec3 halfVec = normalize(inLightVec + eyeDir);
+				float NdotH = max(dot(normal, halfVec), 0.0); 
+				float NdotV = max(dot(normal, eyeDir), 0.0); 
+				float VdotH = max(dot(eyeDir, halfVec), 0.0);
+		
+				// Geometric attenuation
+				float NH2 = 2.0 * NdotH;
+				float g1 = (NH2 * NdotV) / VdotH;
+				float g2 = (NH2 * NdotL) / VdotH;
+				float geoAtt = min(1.0, min(g1, g2));
+
+				const float F0 = 0.6;
+				const float k = 0.2;
+
+				// Fresnel (schlick approximation)
+				float fresnel = pow(1.0 - VdotH, 5.0);
+				fresnel *= (1.0 - F0);
+				fresnel += F0;
+		
+				float spec = (fresnel * geoAtt) / (NdotV * NdotL * 3.14);
+ 
+				color = texture(samplerEnvMap, envMapEquirect(reflect(-wViewVec, wNormal)));	 	
+
+				color = vec4(color.rgb * NdotL * (k + spec * (1.0 - k)), 1.0);
+			}
+			break;
+
+		case 2: // Refract			
+			{
+				vec3 wViewVec = mat3(inInvModelView) * normalize(inViewVec);
+				vec3 wNormal = mat3(inInvModelView) * inNormal;
+				color = texture(samplerEnvMap, envMapEquirect(refract(-wViewVec, wNormal, 1.0/1.6)));		
+			}
+			break;
+	}
+
+
+	// Color with manual exposure into attachment 0
+	outColor0.rgb = vec3(1.0) - exp(-color.rgb * ubo.exposure);
+
+	// Bright parts for bloom into attachment 1
+	float l = dot(outColor0.rgb, vec3(0.2126, 0.7152, 0.0722));
+	float threshold = 0.75;
+	outColor1.rgb = (l > threshold) ? outColor0.rgb : vec3(0.0);
+	outColor1.a = 1.0;
+}

data/shaders/hdr/gbuffer.vert

@@ -0,0 +1,51 @@
+#version 450
+
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_ARB_shading_language_420pack : enable
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+
+layout (constant_id = 0) const int type = 0;
+
+layout (binding = 0) uniform UBO {
+	mat4 projection;
+	mat4 modelview;
+} ubo;
+
+layout (location = 0) out vec3 outUVW;
+layout (location = 1) out vec3 outPos;
+layout (location = 2) out vec3 outNormal;
+layout (location = 3) out vec3 outViewVec;
+layout (location = 4) out vec3 outLightVec;
+layout (location = 5) out mat4 outInvModelView;
+
+out gl_PerVertex 
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outUVW = inPos;
+	outUVW.x *= -1.0;
+
+	switch(type) {
+		case 0: // Skybox
+			outPos = vec3(mat3(ubo.modelview) * inPos);
+			gl_Position = vec4(ubo.projection * vec4(outPos, 1.0));
+			break;
+		case 1: // Object
+			outPos = vec3(ubo.modelview * vec4(inPos, 1.0));
+			gl_Position = ubo.projection * ubo.modelview * vec4(inPos.xyz, 1.0);
+			break;
+	}
+	outPos = vec3(ubo.modelview * vec4(inPos, 1.0));
+	outNormal = mat3(ubo.modelview) * inNormal;	
+	
+	outInvModelView = inverse(ubo.modelview);
+
+	vec3 lightPos = vec3(0.0f, -5.0f, 5.0f);
+	outLightVec = lightPos.xyz - outPos.xyz;
+	outViewVec = -outPos.xyz;		
+}