Add shaders re-implemented in HLSL

These were written against the shaders at revision eddd724e7.
There have been changes made since then, which will need to be mirrored.

See `data/hlsl/README.md` for the current status of each sample.

data/hlsl/deferredmultisampling/debug.frag

@@ -0,0 +1,53 @@
+// Copyright 2020 Google LLC
+
+Texture2DMS<float4> texturePosition : register(t1);
+SamplerState samplerPosition : register(s1);
+Texture2DMS<float4> textureNormal : register(t2);
+SamplerState samplerNormal : register(s2);
+Texture2DMS<float4> textureAlbedo : register(t3);
+SamplerState samplerAlbedo : register(s3);
+
+[[vk::constant_id(0)]] const int NUM_SAMPLES = 8;
+
+float4 resolve(Texture2DMS<float4> tex, int2 uv)
+{
+	float4 result = float4(0.0, 0.0, 0.0, 0.0);
+	int count = 0;
+	for (int i = 0; i < NUM_SAMPLES; i++)
+	{
+		uint status = 0;
+		float4 val = tex.Load(uv, i, int2(0, 0), status);
+		result += val;
+		count++;
+	}
+	return result / float(NUM_SAMPLES);
+}
+
+float4 main([[vk::location(0)]] float3 inUV : TEXCOORD0) : SV_TARGET
+{
+	int2 attDim; int sampleCount;
+	texturePosition.GetDimensions(attDim.x, attDim.y, sampleCount);
+	int2 UV = int2(inUV.xy * attDim * 2.0);
+
+	int index = 0;
+	if (inUV.x > 0.5)
+	{
+		index = 1;
+		UV.x -= attDim.x;
+	}
+	if (inUV.y > 0.5)
+	{
+		index = 2;
+		UV.y -= attDim.y;
+	}
+
+	float3 components[3];
+	components[0] = resolve(texturePosition, UV).rgb;
+	components[1] = resolve(textureNormal, UV).rgb;
+	components[2] = resolve(textureAlbedo, UV).rgb;
+	// Uncomment to display specular component
+	//components[2] = float3(textureAlbedo.Sample(samplerAlbedo, inUV.xt).a);
+
+	// Select component depending on UV
+	return float4(components[index], 1);
+}

data/hlsl/deferredmultisampling/debug.vert

@@ -0,0 +1,23 @@
+// Copyright 2020 Google LLC
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 UV : TEXCOORD0;
+};
+
+VSOutput main(uint VertexIndex : SV_VertexID)
+{
+	VSOutput output = (VSOutput)0;
+	output.UV = float3((VertexIndex << 1) & 2, VertexIndex & 2, 0.0);
+	output.Pos = float4(output.UV.xy * 2.0f - 1.0f, 0.0f, 1.0f);
+	return output;
+}

data/hlsl/deferredmultisampling/deferred.frag

@@ -0,0 +1,104 @@
+// Copyright 2020 Google LLC
+
+Texture2DMS<float4> texturePosition : register(t1);
+SamplerState samplerPosition : register(s1);
+Texture2DMS<float4> textureNormal : register(t2);
+SamplerState samplerNormal : register(s2);
+Texture2DMS<float4> textureAlbedo : register(t3);
+SamplerState samplerAlbedo : register(s3);
+
+struct Light {
+	float4 position;
+	float3 color;
+	float radius;
+};
+
+struct UBO
+{
+	Light lights[6];
+	float4 viewPos;
+	int2 windowSize;
+};
+
+cbuffer ubo : register(b4) { UBO ubo; }
+
+[[vk::constant_id(0)]] const int NUM_SAMPLES = 8;
+
+#define NUM_LIGHTS 6
+
+// Manual resolve for MSAA samples
+float4 resolve(Texture2DMS<float4> tex, int2 uv)
+{
+	float4 result = float4(0.0, 0.0, 0.0, 0.0);
+	for (int i = 0; i < NUM_SAMPLES; i++)
+	{
+		uint status = 0;
+		float4 val = tex.Load(uv, i, int2(0, 0), status);
+		result += val;
+	}
+	// Average resolved samples
+	return result / float(NUM_SAMPLES);
+}
+
+float3 calculateLighting(float3 pos, float3 normal, float4 albedo)
+{
+	float3 result = float3(0.0, 0.0, 0.0);
+
+	for(int i = 0; i < NUM_LIGHTS; ++i)
+	{
+		// Vector to light
+		float3 L = ubo.lights[i].position.xyz - pos;
+		// Distance from light to fragment position
+		float dist = length(L);
+
+		// Viewer to fragment
+		float3 V = ubo.viewPos.xyz - pos;
+		V = normalize(V);
+
+		// Light to fragment
+		L = normalize(L);
+
+		// Attenuation
+		float atten = ubo.lights[i].radius / (pow(dist, 2.0) + 1.0);
+
+		// Diffuse part
+		float3 N = normalize(normal);
+		float NdotL = max(0.0, dot(N, L));
+		float3 diff = ubo.lights[i].color * albedo.rgb * NdotL * atten;
+
+		// Specular part
+		float3 R = reflect(-L, N);
+		float NdotR = max(0.0, dot(R, V));
+		float3 spec = ubo.lights[i].color * albedo.a * pow(NdotR, 8.0) * atten;
+
+		result += diff + spec;
+	}
+	return result;
+}
+
+float4 main([[vk::location(0)]] float2 inUV : TEXCOORD0) : SV_TARGET
+{
+	int2 attDim; int sampleCount;
+	texturePosition.GetDimensions(attDim.x, attDim.y, sampleCount);
+	int2 UV = int2(inUV * attDim);
+
+	#define ambient 0.15
+
+	// Ambient part
+	float4 alb = resolve(textureAlbedo, UV);
+	float3 fragColor = float3(0.0, 0.0, 0.0);
+
+	// Calualte lighting for every MSAA sample
+	for (int i = 0; i < NUM_SAMPLES; i++)
+	{
+		uint status = 0;
+		float3 pos = texturePosition.Load(UV, i, int2(0, 0), status).rgb;
+		float3 normal = textureNormal.Load(UV, i, int2(0, 0), status).rgb;
+		float4 albedo = textureAlbedo.Load(UV, i, int2(0, 0), status);
+		fragColor += calculateLighting(pos, normal, albedo);
+	}
+
+	fragColor = (alb.rgb * ambient) + fragColor / float(NUM_SAMPLES);
+
+	return float4(fragColor, 1.0);
+}

data/hlsl/deferredmultisampling/deferred.vert

@@ -0,0 +1,23 @@
+// Copyright 2020 Google LLC
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float2 UV : TEXCOORD0;
+};
+
+VSOutput main(uint VertexIndex : SV_VertexID)
+{
+	VSOutput output = (VSOutput)0;
+	output.UV = float2((VertexIndex << 1) & 2, VertexIndex & 2);
+	output.Pos = float4(output.UV * 2.0f - 1.0f, 0.0f, 1.0f);
+	return output;
+}

data/hlsl/deferredmultisampling/mrt.frag

@@ -0,0 +1,40 @@
+// Copyright 2020 Google LLC
+
+Texture2D textureColor : register(t1);
+SamplerState samplerColor : register(s1);
+Texture2D textureNormalMap : register(t2);
+SamplerState samplerNormalMap : register(s2);
+
+struct VSOutput
+{
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float2 UV : TEXCOORD0;
+[[vk::location(2)]] float3 Color : COLOR0;
+[[vk::location(3)]] float3 WorldPos : POSITION0;
+[[vk::location(4)]] float3 Tangent : TEXCOORD1;
+};
+
+struct FSOutput
+{
+	float4 Position : SV_TARGET0;
+	float4 Normal : SV_TARGET1;
+	float4 Albedo : SV_TARGET2;
+};
+
+FSOutput main(VSOutput input)
+{
+	FSOutput output = (FSOutput)0;
+	output.Position = float4(input.WorldPos, 1.0);
+
+	// Calculate normal in tangent space
+	float3 N = normalize(input.Normal);
+	N.y = -N.y;
+	float3 T = normalize(input.Tangent);
+	float3 B = cross(N, T);
+	float3x3 TBN = float3x3(T, B, N);
+	float3 tnorm = mul(normalize(textureNormalMap.Sample(samplerNormalMap, input.UV).xyz * 2.0 - float3(1.0, 1.0, 1.0)), TBN);
+	output.Normal = float4(tnorm, 1.0);
+
+	output.Albedo = textureColor.Sample(samplerColor, input.UV);
+	return output;
+}

data/hlsl/deferredmultisampling/mrt.vert

@@ -0,0 +1,54 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float4 Pos : POSITION0;
+[[vk::location(1)]] float2 UV : TEXCOORD0;
+[[vk::location(2)]] float3 Color : COLOR0;
+[[vk::location(3)]] float3 Normal : NORMAL0;
+[[vk::location(4)]] float3 Tangent : TEXCOORD1;
+};
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+	float4x4 view;
+	float4 instancePos[3];
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float2 UV : TEXCOORD0;
+[[vk::location(2)]] float3 Color : COLOR0;
+[[vk::location(3)]] float3 WorldPos : POSITION0;
+[[vk::location(4)]] float3 Tangent : TEXCOORD1;
+};
+
+VSOutput main(VSInput input, uint InstanceIndex : SV_InstanceID)
+{
+	VSOutput output = (VSOutput)0;
+	float4 tmpPos = input.Pos + ubo.instancePos[InstanceIndex];
+
+	output.Pos = mul(ubo.projection, mul(ubo.view, mul(ubo.model, tmpPos)));
+
+	output.UV = input.UV;
+	output.UV.y = 1.0 - output.UV.y;
+
+	// Vertex position in world space
+	output.WorldPos = mul(ubo.model, tmpPos).xyz;
+	// GL to Vulkan coord space
+	output.WorldPos.y = -output.WorldPos.y;
+
+	// Normal in world space
+	output.Normal = normalize(input.Normal);
+	output.Tangent = normalize(input.Tangent);
+
+	// Currently just vertex color
+	output.Color = input.Color;
+	return output;
+}