Add shaders re-implemented in HLSL

These were written against the shaders at revision eddd724e7.
There have been changes made since then, which will need to be mirrored.

See `data/hlsl/README.md` for the current status of each sample.

data/hlsl/geometryshader/base.frag

@@ -0,0 +1,6 @@
+// Copyright 2020 Google LLC
+
+float4 main([[vk::location(0)]] float3 Color : COLOR0) : SV_TARGET
+{
+	return float4(Color, 1.0);
+}

data/hlsl/geometryshader/base.vert

@@ -0,0 +1,21 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+};
+
+struct VSOutput
+{
+[[vk::location(0)]] float4 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+};
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+	output.Normal = input.Normal;
+	output.Pos = float4(input.Pos.xyz, 1.0);
+	return output;
+}

data/hlsl/geometryshader/mesh.frag

@@ -0,0 +1,21 @@
+// Copyright 2020 Google LLC
+
+struct GSOutput
+{
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+};
+
+float4 main(GSOutput input) : SV_TARGET
+{
+	float3 N = normalize(input.Normal);
+	float3 L = normalize(input.LightVec);
+	float3 V = normalize(input.ViewVec);
+	float3 R = reflect(-L, N);
+	float3 ambient = float3(0.1, 0.1, 0.1);
+	float3 diffuse = max(dot(N, L), 0.0) * float3(1.0, 1.0, 1.0);
+	float3 specular = pow(max(dot(R, V), 0.0), 16.0) * float3(0.75, 0.75, 0.75);
+	return float4((ambient + diffuse) * input.Color.rgb + specular, 1.0);
+}

data/hlsl/geometryshader/mesh.vert

@@ -0,0 +1,40 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float4 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float3 Color : COLOR0;
+};
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+};
+cbuffer ubo : register(b0) { UBO ubo; };
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+};
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+	output.Normal = input.Normal;
+	output.Color = input.Color;
+	output.Pos = mul(ubo.projection, mul(ubo.model, input.Pos));
+
+	float4 pos = mul(ubo.model, float4(input.Pos.xyz, 1.0));
+	output.Normal = mul((float4x3)ubo.model, input.Normal).xyz;
+
+	float3 lightPos = float3(1.0f, -1.0f, 1.0f);
+	output.LightVec = lightPos.xyz - pos.xyz;
+	output.ViewVec = -pos.xyz;
+	return output;
+}

data/hlsl/geometryshader/normaldebug.geom

@@ -0,0 +1,43 @@
+// Copyright 2020 Google LLC
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+};
+
+cbuffer ubo : register(b1) { UBO ubo; }
+
+struct VSOutput
+{
+[[vk::location(0)]] float4 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+};
+
+struct GSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 Color : COLOR0;
+};
+
+[maxvertexcount(6)]
+void main(triangle VSOutput input[3], inout LineStream<GSOutput> outStream)
+{
+	float normalLength = 0.02;
+	for(int i=0; i<3; i++)
+	{
+		float3 pos = input[i].Pos.xyz;
+		float3 normal = input[i].Normal.xyz;
+
+		GSOutput output = (GSOutput)0;
+		output.Pos = mul(ubo.projection, mul(ubo.model, float4(pos, 1.0)));
+		output.Color = float3(1.0, 0.0, 0.0);
+		outStream.Append( output );
+
+		output.Pos = mul(ubo.projection, mul(ubo.model, float4(pos + normal * normalLength, 1.0)));
+		output.Color = float3(0.0, 0.0, 1.0);
+		outStream.Append( output );
+
+		outStream.RestartStrip();
+	}
+}