Add shaders re-implemented in HLSL

These were written against the shaders at revision eddd724e7.
There have been changes made since then, which will need to be mirrored.

See `data/hlsl/README.md` for the current status of each sample.

data/hlsl/multiview/multiview.frag

@@ -0,0 +1,21 @@
+// Copyright 2020 Google LLC
+
+struct VSOutput
+{
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+};
+
+float4 main(VSOutput input) : SV_TARGET
+{
+	float3 N = normalize(input.Normal);
+	float3 L = normalize(input.LightVec);
+	float3 V = normalize(input.ViewVec);
+	float3 R = reflect(-L, N);
+	float3 ambient = float3(0.1, 0.1, 0.1);
+	float3 diffuse = max(dot(N, L), 0.0) * float3(1.0, 1.0, 1.0);
+	float3 specular = pow(max(dot(R, V), 0.0), 16.0) * float3(0.75, 0.75, 0.75);
+	return float4((ambient + diffuse) * input.Color.rgb + specular, 1.0);
+}

data/hlsl/multiview/multiview.vert

@@ -0,0 +1,43 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float3 Color : COLOR0;
+};
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+};
+
+struct UBO
+{
+	float4x4 projection[2];
+	float4x4 modelview[2];
+	float4 lightPos;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+VSOutput main(VSInput input, uint ViewIndex : SV_ViewID)
+{
+	VSOutput output = (VSOutput)0;
+	output.Color = input.Color;
+	output.Normal = mul((float3x3)ubo.modelview[ViewIndex], input.Normal);
+
+	float4 pos = float4(input.Pos.xyz, 1.0);
+	float4 worldPos = mul(ubo.modelview[ViewIndex], pos);
+
+	float3 lPos = mul(ubo.modelview[ViewIndex], ubo.lightPos).xyz;
+	output.LightVec = lPos - worldPos.xyz;
+	output.ViewVec = -worldPos.xyz;
+
+	output.Pos = mul(ubo.projection[ViewIndex], worldPos);
+	return output;
+}

data/hlsl/multiview/viewdisplay.frag

@@ -0,0 +1,25 @@
+// Copyright 2020 Google LLC
+
+Texture2DArray textureView : register(t1);
+SamplerState samplerView : register(s1);
+
+struct UBO
+{
+	[[vk::offset(272)]] float distortionAlpha;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+[[vk::constant_id(0)]] const float VIEW_LAYER = 0.0f;
+
+float4 main([[vk::location(0)]] float2 inUV : TEXCOORD0) : SV_TARGET
+{
+	const float alpha = ubo.distortionAlpha;
+
+	float2 p1 = float2(2.0 * inUV - 1.0);
+	float2 p2 = p1 / (1.0 - alpha * length(p1));
+	p2 = (p2 + 1.0) * 0.5;
+
+	bool inside = ((p2.x >= 0.0) && (p2.x <= 1.0) && (p2.y >= 0.0 ) && (p2.y <= 1.0));
+	return inside ? textureView.Sample(samplerView, float3(p2, VIEW_LAYER)) : float4(0.0, 0.0, 0.0, 0.0);
+}

data/hlsl/multiview/viewdisplay.vert

@@ -0,0 +1,15 @@
+// Copyright 2020 Google LLC
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float2 UV : TEXCOORD0;
+};
+
+VSOutput main(uint VertexIndex : SV_VertexID)
+{
+	VSOutput output = (VSOutput)0;
+	output.UV = float2((VertexIndex << 1) & 2, VertexIndex & 2);
+	output.Pos = float4(output.UV * 2.0f - 1.0f, 0.0f, 1.0f);
+	return output;
+}