Add shaders re-implemented in HLSL

These were written against the shaders at revision eddd724e7.
There have been changes made since then, which will need to be mirrored.

See `data/hlsl/README.md` for the current status of each sample.

data/hlsl/radialblur/colorpass.frag

@@ -0,0 +1,23 @@
+// Copyright 2020 Google LLC
+
+Texture2D textureGradientRamp : register(t1);
+SamplerState samplerGradientRamp : register(s1);
+
+struct VSOutput
+{
+[[vk::location(0)]] float3 Color : COLOR0;
+[[vk::location(1)]] float2 UV : TEXCOORD0;
+};
+
+float4 main(VSOutput input) : SV_TARGET
+{
+	// Use max. color channel value to detect bright glow emitters
+	if ((input.Color.r >= 0.9) || (input.Color.g >= 0.9) || (input.Color.b >= 0.9))
+	{
+		return float4(textureGradientRamp.Sample(samplerGradientRamp, input.UV).rgb, 1);
+	}
+	else
+	{
+		return float4(input.Color, 1);
+	}
+}

data/hlsl/radialblur/colorpass.vert

@@ -0,0 +1,32 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(2)]] float3 Color : COLOR0;
+};
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+	float gradientPos;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 Color : COLOR0;
+[[vk::location(1)]] float2 UV : TEXCOORD0;
+};
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+	output.Color = input.Color;
+	output.UV = float2(ubo.gradientPos, 0.0f);
+	output.Pos = mul(ubo.projection, mul(ubo.model, float4(input.Pos, 1.0)));
+	return output;
+}

data/hlsl/radialblur/phongpass.frag

@@ -0,0 +1,35 @@
+// Copyright 2020 Google LLC
+
+Texture2D textureGradientRamp : register(t1);
+SamplerState samplerGradientRamp : register(s1);
+
+struct VSOutput
+{
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float3 EyePos : POSITION0;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+[[vk::location(4)]] float2 UV : TEXCOORD0;
+};
+
+float4 main(VSOutput input) : SV_TARGET
+{
+	// No light calculations for glow color
+	// Use max. color channel value
+	// to detect bright glow emitters
+	if ((input.Color.r >= 0.9) || (input.Color.g >= 0.9) || (input.Color.b >= 0.9))
+	{
+		return float4(textureGradientRamp.Sample(samplerGradientRamp, input.UV).rgb, 1);
+	}
+	else
+	{
+		float3 Eye = normalize(-input.EyePos);
+		float3 Reflected = normalize(reflect(-input.LightVec, input.Normal));
+
+		float4 IAmbient = float4(0.2, 0.2, 0.2, 1.0);
+		float4 IDiffuse = float4(0.5, 0.5, 0.5, 0.5) * max(dot(input.Normal, input.LightVec), 0.0);
+		float specular = 0.25;
+		float4 ISpecular = float4(0.5, 0.5, 0.5, 1.0) * pow(max(dot(Reflected, Eye), 0.0), 4.0) * specular;
+		return float4((IAmbient + IDiffuse) * float4(input.Color, 1.0) + ISpecular);
+	}
+}

data/hlsl/radialblur/phongpass.vert

@@ -0,0 +1,40 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float4 Pos : POSITION0;
+[[vk::location(2)]] float3 Color : COLOR0;
+[[vk::location(3)]] float3 Normal : NORMAL0;
+};
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+	float gradientPos;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float3 EyePos : POSITION0;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+[[vk::location(4)]] float2 UV : TEXCOORD0;
+};
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+	output.Normal = input.Normal;
+	output.Color = input.Color;
+	output.UV = float2(ubo.gradientPos, 0.0);
+	output.Pos = mul(ubo.projection, mul(ubo.model, input.Pos));
+	output.EyePos = mul(ubo.model, input.Pos).xyz;
+	float4 lightPos = float4(0.0, 0.0, -5.0, 1.0);// * ubo.model;
+	output.LightVec = normalize(lightPos.xyz - input.Pos.xyz);
+	return output;
+}

data/hlsl/radialblur/radialblur.frag

@@ -0,0 +1,35 @@
+// Copyright 2020 Google LLC
+
+Texture2D textureColor : register(t1);
+SamplerState samplerColor : register(s1);
+
+struct UBO
+{
+	float radialBlurScale;
+	float radialBlurStrength;
+	float2 radialOrigin;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+float4 main([[vk::location(0)]] float2 inUV : TEXCOORD0) : SV_TARGET
+{
+	int2 texDim;
+	textureColor.GetDimensions(texDim.x, texDim.y);
+	float2 radialSize = float2(1.0 / texDim.x, 1.0 / texDim.y);
+
+	float2 UV = inUV;
+
+	float4 color = float4(0.0, 0.0, 0.0, 0.0);
+	UV += radialSize * 0.5 - ubo.radialOrigin;
+
+	#define samples 32
+
+	for (int i = 0; i < samples; i++)
+	{
+		float scale = 1.0 - ubo.radialBlurScale * (float(i) / float(samples-1));
+		color += textureColor.Sample(samplerColor, UV * scale + ubo.radialOrigin);
+	}
+
+	return (color / samples) * ubo.radialBlurStrength;
+}

data/hlsl/radialblur/radialblur.vert

@@ -0,0 +1,15 @@
+// Copyright 2020 Google LLC
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float2 UV : TEXCOORD0;
+};
+
+VSOutput main(uint VertexIndex : SV_VertexID)
+{
+	VSOutput output = (VSOutput)0;
+	output.UV = float2((VertexIndex << 1) & 2, VertexIndex & 2);
+	output.Pos = float4(output.UV * 2.0f - 1.0f, 0.0f, 1.0f);
+	return output;
+}