Added cube map array sample

data/shaders/glsl/texturecubemaparray/reflect.frag

@@ -0,0 +1,39 @@
+#version 450
+
+layout (binding = 1) uniform samplerCubeArray samplerCubeMapArray;
+
+layout (binding = 0) uniform UBO
+{
+	mat4 projection;
+	mat4 model;
+	mat4 invModel;
+	float lodBias;
+	int cubeMapIndex;
+} ubo;
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec3 inViewVec;
+layout (location = 3) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main()
+{
+	vec3 cI = normalize (inPos);
+	vec3 cR = reflect (cI, normalize(inNormal));
+
+	cR = vec3(ubo.invModel * vec4(cR, 0.0));
+	cR.y *= -1.0;
+
+	vec4 color = texture(samplerCubeMapArray, vec4(cR, ubo.cubeMapIndex), ubo.lodBias);
+
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 ambient = vec3(0.5) * color.rgb;
+	vec3 diffuse = max(dot(N, L), 0.0) * vec3(1.0);
+	vec3 specular = pow(max(dot(R, V), 0.0), 16.0) * vec3(0.5);
+	outFragColor = vec4(ambient + diffuse * color.rgb + specular, 1.0);
+}

data/shaders/glsl/texturecubemaparray/reflect.vert

@@ -0,0 +1,30 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+
+layout (binding = 0) uniform UBO
+{
+	mat4 projection;
+	mat4 model;
+	mat4 invModel;
+	float lodBias;
+	int cubeMapIndex;
+} ubo;
+
+layout (location = 0) out vec3 outPos;
+layout (location = 1) out vec3 outNormal;
+layout (location = 2) out vec3 outViewVec;
+layout (location = 3) out vec3 outLightVec;
+
+void main()
+{
+	gl_Position = ubo.projection * ubo.model * vec4(inPos.xyz, 1.0);
+
+	outPos = vec3(ubo.model * vec4(inPos, 1.0));
+	outNormal = mat3(ubo.model) * inNormal;
+
+	vec3 lightPos = vec3(0.0f, -5.0f, 5.0f);
+	outLightVec = lightPos.xyz - outPos.xyz;
+	outViewVec = -outPos.xyz;
+}

data/shaders/glsl/texturecubemaparray/skybox.frag

@@ -0,0 +1,21 @@
+#version 450
+
+layout (binding = 1) uniform samplerCubeArray samplerCubeMapArray;
+
+layout (binding = 0) uniform UBO
+{
+	mat4 projection;
+	mat4 model;
+	mat4 invModel;
+	float lodBias;
+	int cubeMapIndex;
+} ubo;
+
+layout (location = 0) in vec3 inUVW;
+
+layout (location = 0) out vec4 outFragColor;
+
+void main() 
+{
+	outFragColor = texture(samplerCubeMapArray, vec4(inUVW, ubo.cubeMapIndex), ubo.lodBias);
+}

data/shaders/glsl/texturecubemaparray/skybox.vert

@@ -0,0 +1,21 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection;
+	mat4 model;
+	mat4 invModel;
+	float lodBias;
+	int cubeMapIndex;
+} ubo;
+
+layout (location = 0) out vec3 outUVW;
+
+void main() 
+{
+	outUVW = inPos;
+	outUVW.y *= -1.0;
+	gl_Position = ubo.projection * ubo.model * vec4(inPos.xyz, 1.0);
+}