Added cube map array sample

data/shaders/hlsl/texturecubemaparray/reflect.frag

@@ -0,0 +1,44 @@
+// Copyright 2020 Google LLC
+
+TextureCubeArray textureCubeMapArray : register(t1);
+SamplerState samplerCubeMapArray : register(s1);
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+	float4x4 invModel;
+	float lodBias;
+	int cubeMapIndex;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float LodBias : TEXCOORD3;
+[[vk::location(3)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(4)]] float3 LightVec : TEXCOORD2;
+};
+
+float4 main(VSOutput input) : SV_TARGET
+{
+	float3 cI = normalize (input.ViewVec);
+	float3 cR = reflect (cI, normalize(input.Normal));
+
+	cR = mul(ubo.invModel, float4(cR, 0.0)).xyz;
+	cR *= float3(-1.0, 1.0, -1.0);
+
+	float4 color = textureCubeMapArray.SampleLevel(samplerCubeMapArray, float4(cR, ubo.cubeMapIndex), input.LodBias);
+
+	float3 N = normalize(input.Normal);
+	float3 L = normalize(input.LightVec);
+	float3 V = normalize(input.ViewVec);
+	float3 R = reflect(-L, N);
+	float3 ambient = float3(0.5, 0.5, 0.5) * color.rgb;
+	float3 diffuse = max(dot(N, L), 0.0) * float3(1.0, 1.0, 1.0);
+	float3 specular = pow(max(dot(R, V), 0.0), 16.0) * float3(0.5, 0.5, 0.5);
+	return float4(ambient + diffuse * color.rgb + specular, 1.0);
+}

data/shaders/hlsl/texturecubemaparray/reflect.vert

@@ -0,0 +1,42 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+};
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+	float4x4 invModel;
+	float lodBias;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 WorldPos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float LodBias : TEXCOORD3;
+[[vk::location(3)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(4)]] float3 LightVec : TEXCOORD2;
+};
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+	output.Pos = mul(ubo.projection, mul(ubo.model, float4(input.Pos.xyz, 1.0)));
+
+	output.WorldPos = mul(ubo.model, float4(input.Pos, 1.0)).xyz;
+	output.Normal = mul((float3x3)ubo.model, input.Normal);
+	output.LodBias = ubo.lodBias;
+
+	float3 lightPos = float3(0.0f, -5.0f, 5.0f);
+	output.LightVec = lightPos.xyz - output.WorldPos.xyz;
+	output.ViewVec = -output.WorldPos;
+	return output;
+}

data/shaders/hlsl/texturecubemaparray/skybox.frag

@@ -0,0 +1,20 @@
+// Copyright 2020 Google LLC
+
+TextureCubeArray textureCubeMapArray : register(t1);
+SamplerState samplerCubeMapArray : register(s1);
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+	float4x4 invModel;
+	float lodBias;
+	int cubeMapIndex;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+float4 main([[vk::location(0)]] float3 inUVW : TEXCOORD0) : SV_TARGET
+{
+	return textureCubeMapArray.SampleLevel(samplerCubeMapArray, float4(inUVW, ubo.cubeMapIndex), ubo.lodBias);
+}

data/shaders/hlsl/texturecubemaparray/skybox.vert

@@ -0,0 +1,27 @@
+// Copyright 2020 Google LLC
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 model;
+	float4x4 invModel;
+	float lodBias;
+	int cubeMapIndex;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 UVW : TEXCOORD0;
+};
+
+VSOutput main([[vk::location(0)]] float3 Pos : POSITION0)
+{
+	VSOutput output = (VSOutput)0;
+	output.UVW = Pos;
+	output.UVW.y *= -1.0;
+	output.Pos = mul(ubo.projection, mul(ubo.model, float4(Pos.xyz, 1.0)));
+	return output;
+}