Merge glTF scene rendering sample (#744)

* Started reworking the scene rendering to sample
Use glTF instead of ASSIMP, per-material pipelines, material loading, etc.

* Visibility toggle for scene nodes

* Fixed lighting, updated GLSL and HLSL shaders

* Renamed sample

* Code-Cleanup, comments, validation fixes

* Android build

* Started on tutorial for glTF scene rendering sample

* Minor code cleanup

* Adding new chapters to the tutorial for glTF scene rendering sample

* Added info on normal map shader bindings, spelling

* Added drawing chapter

* Getter for texture descriptors

Makes code a easier to read

* Renamed glTF scene sample

* Add markdown files to projects

* Updated readme, separate chapter for glTF samples

* Comments

* Removed unused screenshot

data/shaders/hlsl/gltfscenerendering/scene.frag

@@ -0,0 +1,44 @@
+// Copyright 2020 Google LLC
+
+Texture2D textureColorMap : register(t0, space1);
+SamplerState samplerColorMap : register(s0, space1);
+Texture2D textureNormalMap : register(t1, space1);
+SamplerState samplerNormalMap : register(s1, space1);
+
+[[vk::constant_id(0)]] const bool ALPHA_MASK = false;
+[[vk::constant_id(1)]] const float ALPHA_MASK_CUTOFF = 0.0;
+
+struct VSOutput
+{
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float2 UV : TEXCOORD0;
+[[vk::location(3)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(4)]] float3 LightVec : TEXCOORD2;
+[[vk::location(5)]] float4 Tangent : TEXCOORD3;
+};
+
+float4 main(VSOutput input) : SV_TARGET
+{
+	float4 color = textureColorMap.Sample(samplerColorMap, input.UV) * float4(input.Color, 1.0);
+
+	if (ALPHA_MASK) {
+		if (color.a < ALPHA_MASK_CUTOFF) {
+			discard;
+		}
+	}
+
+	float3 N = normalize(input.Normal);
+	float3 T = normalize(input.Tangent.xyz);
+	float3 B = cross(input.Normal, input.Tangent.xyz) * input.Tangent.w;
+	float3x3 TBN = float3x3(T, B, N);
+	N = mul(normalize(textureNormalMap.Sample(samplerNormalMap, input.UV).xyz * 2.0 - float3(1.0, 1.0, 1.0)), TBN);
+
+	const float ambient = 0.1;
+	float3 L = normalize(input.LightVec);
+	float3 V = normalize(input.ViewVec);
+	float3 R = reflect(-L, N);
+	float3 diffuse = max(dot(N, L), ambient).rrr;
+	float3 specular = pow(max(dot(R, V), 0.0), 32.0);
+	return float4(diffuse * color.rgb + specular, color.a);
+}

data/shaders/hlsl/gltfscenerendering/scene.vert

@@ -0,0 +1,54 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float2 UV : TEXCOORD0;
+[[vk::location(3)]] float3 Color : COLOR0;
+[[vk::location(4)]] float4 Tangent : TEXCOORD1;
+};
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 view;
+	float4 lightPos;
+	float4 viewPos;
+};
+cbuffer ubo : register(b0) { UBO ubo; };
+
+struct PushConsts {
+	float4x4 model;
+};
+[[vk::push_constant]] PushConsts primitive;
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 Normal : NORMAL0;
+[[vk::location(1)]] float3 Color : COLOR0;
+[[vk::location(2)]] float2 UV : TEXCOORD0;
+[[vk::location(3)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(4)]] float3 LightVec : TEXCOORD2;
+[[vk::location(5)]] float4 Tangent : TEXCOORD3;
+};
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+	output.Normal = input.Normal;
+	output.Color = input.Color;
+	output.UV = input.UV;
+	output.Tangent = input.Tangent;
+
+	float4x4 modelView = mul(ubo.view, primitive.model);
+
+	output.Pos = mul(ubo.projection, mul(modelView, float4(input.Pos.xyz, 1.0)));
+
+	output.Normal = mul((float3x3)primitive.model, input.Normal);
+	float4 pos = mul(primitive.model, float4(input.Pos, 1.0));
+	output.LightVec = ubo.lightPos.xyz - pos.xyz;
+	output.ViewVec = ubo.viewPos.xyz - pos.xyz;
+	return output;
+}