Viewport array example (geometry shader) (wip)

data/shaders/viewportarray/multiview.geom

@@ -0,0 +1,47 @@
+#version 450
+
+#extension GL_ARB_viewport_array : enable
+
+layout (triangles, invocations = 2) in;
+layout (triangle_strip, max_vertices = 3) out;
+
+layout (binding = 0) uniform UBO 
+{
+	mat4 projection[2];
+	mat4 modelview[2];
+	vec4 lightPos;
+} ubo;
+
+layout (location = 0) in vec3 inNormal[];
+layout (location = 1) in vec3 inColor[];
+layout (location = 2) in vec3 inViewVec[];
+layout (location = 3) in vec3 inLightVec[];
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+layout (location = 2) out vec3 outViewVec;
+layout (location = 3) out vec3 outLightVec;
+
+void main(void)
+{	
+	for(int i = 0; i < gl_in.length(); i++)
+	{
+		outNormal = mat3(ubo.modelview[gl_InvocationID]) * inNormal[i];
+		outColor = inColor[i];
+
+		vec4 pos = gl_in[i].gl_Position;
+		vec4 worldPos = (ubo.modelview[gl_InvocationID] * pos);
+		
+		vec3 lPos = vec3(ubo.modelview[gl_InvocationID]  * ubo.lightPos);
+		outLightVec = lPos - worldPos.xyz;
+		outViewVec = -worldPos.xyz;	
+	
+		gl_Position = ubo.projection[gl_InvocationID] * worldPos;
+
+		// Set the viewport index that the vertex will be emitted to
+		gl_ViewportIndex = gl_InvocationID;
+
+		EmitVertex();
+	}
+	EndPrimitive();
+}

data/shaders/viewportarray/scene.frag

@@ -0,0 +1,20 @@
+#version 450
+
+layout (location = 0) in vec3 inNormal;
+layout (location = 1) in vec3 inColor;
+layout (location = 2) in vec3 inViewVec;
+layout (location = 3) in vec3 inLightVec;
+
+layout (location = 0) out vec4 outColor;
+
+void main() 
+{
+	vec3 N = normalize(inNormal);
+	vec3 L = normalize(inLightVec);
+	vec3 V = normalize(inViewVec);
+	vec3 R = reflect(-L, N);
+	vec3 ambient = vec3(0.1);
+	vec3 diffuse = max(dot(N, L), 0.0) * vec3(1.0);
+	vec3 specular = pow(max(dot(R, V), 0.0), 16.0) * vec3(0.75);
+	outColor = vec4((ambient + diffuse) * inColor.rgb + specular, 1.0);		
+}

data/shaders/viewportarray/scene.vert

@@ -0,0 +1,20 @@
+#version 450
+
+layout (location = 0) in vec3 inPos;
+layout (location = 1) in vec3 inNormal;
+layout (location = 2) in vec3 inColor;
+
+layout (location = 0) out vec3 outNormal;
+layout (location = 1) out vec3 outColor;
+
+out gl_PerVertex
+{
+	vec4 gl_Position;
+};
+
+void main() 
+{
+	outColor = inColor;
+	outNormal = inNormal;
+	gl_Position = vec4(inPos.xyz, 1.0);	
+}