/* Copyright (c) 2025, Sascha Willems
 *
 * SPDX-License-Identifier: MIT
 *
 */

struct VSInput
{
	float3 Pos;
	float3 Normal;
	float3 Color;
};

struct VSOutput
{
    float4 Pos : SV_POSITION;
    float3 Normal;
    float3 Color;
    float3 ViewVec;
    float3 LightVec;
};

struct UBO
{
	float4x4 projection;
	float4x4 model;
	float4 lightPos;
};
ConstantBuffer<UBO> ubo;

[shader("vertex")]
VSOutput vertexMain(VSInput input)
{
	VSOutput output;
	output.Normal = input.Normal;
	output.Color = input.Color;
	output.Pos = mul(ubo.projection, mul(ubo.model, float4(input.Pos.xyz, 1.0)));

	float4 pos = mul(ubo.model, float4(input.Pos, 1.0));
	// Output the vertex position using debug printf
	printf("Position = %v4f", pos);

	output.Normal = mul((float4x3)ubo.model, input.Normal).xyz;
	float3 lPos = mul((float4x3)ubo.model, ubo.lightPos.xyz).xyz;
	output.LightVec = lPos - pos.xyz;
	output.ViewVec = -pos.xyz;
	return output;
}

[shader("fragment")]
float4 fragmentMain(VSOutput input)
{
    // Desaturate color
    float3 color = float3(lerp(input.Color, dot(float3(0.2126, 0.7152, 0.0722), input.Color).xxx, 0.65));

    // High ambient colors because mesh materials are pretty dark
    float3 ambient = color * float3(1.0, 1.0, 1.0);
    float3 N = normalize(input.Normal);
    float3 L = normalize(input.LightVec);
    float3 V = normalize(input.ViewVec);
    float3 R = reflect(-L, N);
    float3 diffuse = max(dot(N, L), 0.0) * color;
    float3 specular = pow(max(dot(R, V), 0.0), 16.0) * float3(0.75, 0.75, 0.75);

    float intensity = dot(N, L);
    float shade = 1.0;
    shade = intensity < 0.5 ? 0.75 : shade;
    shade = intensity < 0.35 ? 0.6 : shade;
    shade = intensity < 0.25 ? 0.5 : shade;
    shade = intensity < 0.1 ? 0.25 : shade;

    return float4(input.Color * 3.0 * shade, 1);
}