Add shaders re-implemented in HLSL

These were written against the shaders at revision eddd724e7.
There have been changes made since then, which will need to be mirrored.

See `data/hlsl/README.md` for the current status of each sample.

data/hlsl/texturecubemap/reflect.frag

@@ -0,0 +1,31 @@
+// Copyright 2020 Google LLC
+
+TextureCube textureColor : register(t1);
+SamplerState samplerColor : register(s1);
+
+struct VSOutput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float LodBias : TEXCOORD3;
+[[vk::location(3)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(4)]] float3 LightVec : TEXCOORD2;
+};
+
+float4 main(VSOutput input) : SV_TARGET
+{
+	float3 cI = normalize (input.ViewVec);
+	float3 cR = reflect (cI, normalize(input.Normal));
+	cR.x *= -1;
+
+	float4 color = textureColor.SampleLevel(samplerColor, cR, input.LodBias);
+
+	float3 N = normalize(input.Normal);
+	float3 L = normalize(input.LightVec);
+	float3 V = normalize(input.ViewVec);
+	float3 R = reflect(-L, N);
+	float3 ambient = float3(0.5, 0.5, 0.5) * color.rgb;
+	float3 diffuse = max(dot(N, L), 0.0) * float3(1.0, 1.0, 1.0);
+	float3 specular = pow(max(dot(R, V), 0.0), 16.0) * float3(0.5, 0.5, 0.5);
+	return float4(ambient + diffuse * color.rgb + specular, 1.0);
+}

data/hlsl/texturecubemap/reflect.vert

@@ -0,0 +1,43 @@
+// Copyright 2020 Google LLC
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+};
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 view;
+	float4x4 model;
+	float3 camPos;
+	float lodBias;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 WorldPos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float LodBias : TEXCOORD3;
+[[vk::location(3)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(4)]] float3 LightVec : TEXCOORD2;
+};
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+	output.Pos = mul(ubo.projection, mul(ubo.view, mul(ubo.model, float4(input.Pos.xyz, 1.0))));
+
+	output.WorldPos = mul(ubo.model, float4(input.Pos, 1.0)).xyz;
+	output.Normal = -mul((float3x3)ubo.model, input.Normal);
+	output.LodBias = ubo.lodBias;
+
+	float3 lightPos = float3(0.0f, -5.0f, 5.0f);
+	output.LightVec = lightPos.xyz - output.WorldPos.xyz;
+	output.ViewVec = output.WorldPos - ubo.camPos;
+	return output;
+}

data/hlsl/texturecubemap/skybox.frag

@@ -0,0 +1,9 @@
+// Copyright 2020 Google LLC
+
+TextureCube textureCubeMap : register(t1);
+SamplerState samplerCubeMap : register(s1);
+
+float4 main([[vk::location(0)]] float3 inUVW : TEXCOORD0) : SV_TARGET
+{
+	return textureCubeMap.Sample(samplerCubeMap, inUVW);
+}

data/hlsl/texturecubemap/skybox.vert

@@ -0,0 +1,25 @@
+// Copyright 2020 Google LLC
+
+struct UBO
+{
+	float4x4 projection;
+	float4x4 view;
+	float4x4 model;
+};
+
+cbuffer ubo : register(b0) { UBO ubo; }
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 UVW : TEXCOORD0;
+};
+
+VSOutput main([[vk::location(0)]] float3 Pos : POSITION0)
+{
+	VSOutput output = (VSOutput)0;
+	output.UVW = Pos;
+	output.UVW.x *= -1.0;
+	output.Pos = mul(ubo.projection, mul(ubo.view, mul(ubo.model, float4(Pos.xyz, 1.0))));
+	return output;
+}